Understanding Service Broker Constructs (part 5)

use XCatMgmt
GO
DROP PROC Publication.CatalogChangeQueueReader
GO
CREATE PROCEDURE Publication.CatalogChangeQueueReader
AS
DECLARE @e int, @r int, @MsgTypeName nvarchar(128), @desc varchar(255),
    @MsgXml xml, @AckXml xml (DOCUMENT dbo.GenericAcknowledgementSchema),
    @RemoteSSBGuid uniqueidentifier, @ErrNS varchar(150), @EndDlgNS varchar(150),
    @CatChangeNS varchar(150), @TempXml xml, @NewName varchar(100),
    @SourceProductId int, @ChangeType int, @ConversationGroupId uniqueidentifier,
    @DialogHandle uniqueidentifier

SET @ErrNS = 'http://schemas.microsoft.com/SQL/ServiceBroker/Error'
SET @EndDlgNS = 'http://schemas.microsoft.com/SQL/ServiceBroker/EndDialog'
SET @CatChangeNS = '//samspublishing.com/SS2008/SSB/MessageTypes/
CatalogChangeMessage'

-- Get the SSB guid for the initiator's db
SELECT @RemoteSSBGuid = service_broker_guid
FROM sys.databases
WHERE name = 'AdventureWorks2008';

BEGIN TRAN;
WAITFOR(
    GET CONVERSATION GROUP @ConversationGroupId
    FROM Publication.CatalogChangeQueue
), TIMEOUT 1000

IF @ConversationGroupId IS NULL
BEGIN
    ROLLBACK TRAN
    PRINT '(Target) ConversationGroupId not acquired in time.'
    RETURN
END
ELSE
    PRINT '(Target) ConversationGroupId acquired successfully.';

RECEIVE TOP(1)
    @MsgXml = CAST(message_body as xml),
    @MsgTypeName = message_type_name,
    @DialogHandle = conversation_handle
FROM Publication.CatalogChangeQueue
WHERE conversation_group_id = @ConversationGroupId

SELECT @e = @@ERROR, @r = @@ROWCOUNT
IF @r = 0
BEGIN
    ROLLBACK TRAN
    RETURN
END

IF @e != 0
BEGIN
    ROLLBACK TRAN
    PRINT '(Target) Error during receive.'
    RETURN
END
ELSE
    PRINT '(Target) Message received.'

-- if the msg is of type Error, end the conversation, stating the error
IF @MsgTypeName = @ErrNS
BEGIN
    SELECT @desc = @MsgXml.value('
        declare default element namespace
            "http://schemas.microsoft.com/SQL/ServiceBroker/Error";
        (/Error/Description/text())[1]', 'varchar(255)')

    ROLLBACK TRAN
    PRINT '(Target) Error message received.'
    END CONVERSATION @DialogHandle
    WITH ERROR = 808 DESCRIPTION = @desc
    RETURN
END
-- if the msg is of type EndDialog, end the conversation without error
IF @MsgTypeName = @EndDlgNS
BEGIN
    PRINT '(Target) EndDialog message received.';
    END CONVERSATION @DialogHandle
    RETURN
END

-- if the msg is of type CatalogChangeMessage, update appropriately
IF @MsgTypeName = @CatChangeNS
BEGIN
BEGIN TRY
    -- what kind of change is requested?
    -- (here we only deal with product name and xml changes)
    ;WITH XMLNAMESPACES
    (
        DEFAULT 'urn:www-samspublishing-com:examples:ssb:catalogchange'
    )
    SELECT
        @ChangeType = @MsgXml.value('
            (/CatalogChangeMessage/CatalogChange/@ChangeType)[1]', 'int'),
        @NewName = @MsgXml.value('
            (/CatalogChangeMessage/CatalogChange/@Name)[1]', 'varchar(100)'),
        @SourceProductId = @MsgXml.value('
            (/CatalogChangeMessage/CatalogChange/@SourceProductId)[1]', 'int')

    IF @ChangeType IS NULL OR @NewName IS NULL OR @SourceProductId IS NULL
    BEGIN
        ROLLBACK TRAN
        PRINT '(Target) An xml-selected value is NULL.'
        RETURN
    END

    IF @ChangeType = 2 -- "Update"
    BEGIN
        UPDATE Publication.Product
        SET
            ProductName = @NewName,
            ProductDetailXml = @MsgXml
        WHERE @SourceProductId = SourceProductId
            IF @@ERROR != 0 OR @@ROWCOUNT = 0
        BEGIN
            ROLLBACK TRAN
            PRINT '(Target) Failure during table update.'
            RETURN
        END
        SET @AckXml = '
            <Ack
                xmlns="urn:www-samspublishing-com:examples:ssb:genericack"
                ResultCode="1">
                <ResultMessage    ContentId="' +
                CAST(@SourceProductId as varchar(10)) + '"
                MsgType="1">Success!</ResultMessage></Ack>';

        SEND ON CONVERSATION @DialogHandle
        MESSAGE TYPE
        [//samspublishing.com/SS2008/SSB/MessageTypes/GenericAck]
        (@AckXml)
        PRINT '(Target) Message Sent Successfully.'
    END
END TRY
BEGIN CATCH
    ROLLBACK TRAN
    SELECT @desc = ERROR_MESSAGE()
    -- INSERT dbo.TargetErrs SELECT @desc -- simple error storage table
    PRINT '(Target) Caught error:' + @desc
    END CONVERSATION @DialogHandle
    WITH ERROR = 808 DESCRIPTION = @desc
    RETURN
END CATCH
END
COMMIT TRAN